視頻解碼芯片SAA7113的初始化與控制

摘要：本文首先簡(jiǎn)要介紹了視頻解碼芯片SAA7113的特點(diǎn)與應(yīng)用，然后介紹了初始化時(shí)的寄存器配置，用51單片機(jī)控制7113的方法，最后給出了初始化7113的匯編程序及控制方法。
關(guān)鍵詞：視頻解碼 SAA7113  I2C總線 初始化

引言：
    SAA7113是飛利浦公司視頻解碼系列芯片的一種，非常具有代表性，在很多視頻產(chǎn)品如電視卡、MPEG2、MPEG4中都有應(yīng)用，熟悉了7113的原理后，對(duì)其它系列芯片SAA7114、7115、7118就會(huì)很容易理解。SAA7113的主要作用是把輸入的模擬視頻信號(hào)解碼成標(biāo)準(zhǔn)的“VPO”數(shù)字信號(hào)，相當(dāng)于一種“A/D”器件。7113兼容全球各種視頻標(biāo)準(zhǔn)，在我國(guó)應(yīng)用時(shí)必須根據(jù)我國(guó)的視頻標(biāo)準(zhǔn)來(lái)配置內(nèi)部的寄存器，即初始化，否則7113就不能按要求輸出，可以說(shuō)對(duì)7113進(jìn)行研發(fā)的主要工作就是如何初始化。對(duì)7113初始化需要通過(guò)I2C總線進(jìn)行，本文給出用51單片機(jī)控制的例子。

1． SAA7113的基本原理與應(yīng)用
    SAA7113是一種視頻解碼芯片，它可以輸入4路模擬視頻信號(hào)，通過(guò)內(nèi)部寄存器的不同配置可以對(duì)4路輸入進(jìn)行轉(zhuǎn)換，輸入可以為4路CVBS或2路S視頻（Y/C）信號(hào)，輸出8位“VPO”總線，為標(biāo)準(zhǔn)的ITU 656、YUV 4：2：2格式。

    7113兼容PAL、NTSC、SECAM多種制式，可以自動(dòng)檢測(cè)場(chǎng)頻適用的50或60Hz，可以在PAL、NTSC之間自動(dòng)切換。7113內(nèi)部具有一系列寄存器，可以配置為不同的參數(shù)，對(duì)色度、亮度等的控制都是通過(guò)對(duì)相應(yīng)寄存器改寫(xiě)不同的值，寄存器的讀寫(xiě)需要通過(guò)I2C總線進(jìn)行。

    7113的模擬與數(shù)字部分均采用+3.3V供電，數(shù)字I/O接口可兼容+5V，正常工作時(shí)功耗0.4W, 空閑時(shí)為0.07W。7113需外接24.576MHz晶體，內(nèi)部具有鎖相環(huán)（LLC），可輸出27MHz的系統(tǒng)時(shí)鐘。芯片具有上電自動(dòng)復(fù)位功能，另有外部復(fù)位管腳（CE），低電平復(fù)位，復(fù)位以后輸出總線變?yōu)槿龖B(tài)，待復(fù)位信號(hào)變高后自動(dòng)恢復(fù)，時(shí)鐘丟失、電源電壓降低都會(huì)引起芯片的自動(dòng)復(fù)位。7113為QFP44封裝。
7113的典型應(yīng)用如下圖所示。

2．SAA7113的寄存器簡(jiǎn)要介紹
    SAA7113的地址從00H開(kāi)始，其中14H、18H~1EH、20H~3FH、63H~FFH均為保留地址，沒(méi)有用到，00H、1FH、60H~62H為只讀寄存器，只有以下寄存器可以讀寫(xiě)：01H~05H（前端輸入通道部分），06H~13H、15H~17H（解碼部分），40H~60H（常規(guī)分離數(shù)據(jù)部分）。

    下面列表對(duì)7113中的寄存器進(jìn)行簡(jiǎn)要說(shuō)明，其中默認(rèn)值為芯片復(fù)位后的寄存器默認(rèn)值，設(shè)置值為可以適用于我國(guó)PAL制式的設(shè)置參數(shù)，這些參數(shù)只供參考，詳細(xì)信息請(qǐng)參考7113數(shù)據(jù)手冊(cè)，有些參數(shù)如亮度等可以根據(jù)用戶(hù)的需要適當(dāng)更改。

3．SAA7113寄存器的配置方法
    SAA7113的寄存器配置通過(guò)I2C總線來(lái)進(jìn)行，遵從I2C總線協(xié)議，下面從讀、寫(xiě)兩個(gè)方面來(lái)說(shuō)明操作的格式：

對(duì)7113寄存器的“寫(xiě)”操作：

對(duì)7113寄存器的“讀”操作：

    說(shuō)明：S：起始位，條件是SCL高電平時(shí)SDA有下降沿；
Sr：重復(fù)設(shè)一個(gè)起始位
Slave address W：7113芯片地址+寫(xiě)標(biāo)志，0100 1010 = 4AH，若RTS0通過(guò)3.3K電阻接地，則為48H；
Slave address R：7113芯片地址+寫(xiě)標(biāo)志，0100 1011 = 4BH，若RTS0通過(guò)3.3K電阻接地，則為49H；
ACK-S：7113產(chǎn)生的回應(yīng)信號(hào)；
ACK-m：主機(jī)產(chǎn)生的回應(yīng)信號(hào)；
Subaddress：寄存器地址；
P：停止位，條件是SCL高電平時(shí)SDA有上升沿；
對(duì)多個(gè)寄存器操作時(shí)，寄存器地址有自動(dòng)加1功能。

4．用51單片機(jī)對(duì)7113初始化和控制
    SAA7113的初始化就是對(duì)寄存器配置合適的參數(shù)，使其能夠有符合要求的輸出。寄存器配置通過(guò)I2C總線來(lái)進(jìn)行，很多可以控制I2C總線的器件都可以作為主器件對(duì)7113進(jìn)行初始化，這里介紹用51單片機(jī)初始化7113的例子。

    51單片機(jī)和7113的硬件連接非常簡(jiǎn)單，只要把單片機(jī)的兩個(gè)I/O口（如P1.0、P1.0）直接和7113的SCL、SDA管腳相連，再加上上拉電阻即可。

     用單片機(jī)初始化7113的主要任務(wù)是程序的編寫(xiě)，首先要熟悉I2C總線協(xié)議，根據(jù)I2C總線的原理寫(xiě)出啟動(dòng)、停止、應(yīng)答信號(hào)等的子程序，由子程序再寫(xiě)出發(fā)送、接收1個(gè)字節(jié)的程序，然后根據(jù)7113的寄存器操作格式寫(xiě)出讀寫(xiě)寄存器的程序，最后根據(jù)以上的子程序?qū)懗龀跏蓟?113的程序段。

    對(duì)7113的控制一般是改變色度、亮度等指標(biāo)以及輸出管腳的輸出信號(hào)，這可以通過(guò)修改相應(yīng)寄存器的值來(lái)完成，程序上寫(xiě)出“讀寫(xiě)命令”即可。

    下面以程序段的形式給出初始化SAA7113以及讀寫(xiě)寄存器的具體例子，以供參考。
SDA              BIT   P1.0
SCL              BIT   P1.1
I2C_ERROR        BIT   00H    ；I2C總線數(shù)據(jù)傳輸出錯(cuò)標(biāo)志
DeviceaddressW   EQU   4AH    ；7113器件地址+寫(xiě)
DeviceaddressR   EQU   4BH    ；7113器件地址+讀
Subaddress       EQU   4DH    ；7113寄存器地址字節(jié)在單片機(jī)中的存放地址
DATA_I2C         EQU   50H    ；設(shè)置寫(xiě)入或讀出數(shù)據(jù)在單片機(jī)中的存放地址

；*************啟動(dòng)**************
I2C_START:    SETB   SDA
               NOP
               SETB   SCL
               NOP
               CLR    SDA
               NOP
               CLR    SCL
               RET
;***************停止**************
I2C_STOP:     CLR    SDA
               NOP
               SETB   SCL
               NOP
               SETB   SDA
               NOP
               RET
;************送應(yīng)答位************
SEND_ACK:    CLR    SCL
               NOP
               CLR    SDA
               NOP
               SETB   SCL
               NOP
               NOP
               CLR    SCL
               NOP
               SETB   SDA
               RET
;***********送非應(yīng)答位***********
SEND_NOACK: SETB   SDA
              NOP
              SETB   SCL
              NOP
              NOP
              CLR    SCL
              NOP
              RET
;***********檢查應(yīng)答位************
CHECK_ACK:  NOP
              CLR    SCL
              NOP
              SETB   SDA
              NOP
              SETB   SCL
              NOP
              NOP
              MOV   C, SDA
              MOV   I2C_ERROR, C
              CLR    SCL
              NOP
              RET
;*******發(fā)送1字節(jié)數(shù)據(jù)，待送數(shù)據(jù)在A中******
I2C_SEND_1BYTE:
              MOV   R0,  #8
   SEND100:  RLC    A
              MOV   SDA,  C
              NOP
              SETB   SCL
              NOP
              NOP
              CLR    SCL
              DJNZ   R0, SEND100
              RET
;*******接收1字節(jié)數(shù)據(jù)，接收數(shù)據(jù)放在A中*****
I2C_RECEIVE_1BYTE:
              MOV   R0,  #8
  RECV100:   SETB   SDA
              NOP
              SETB   SCL
              NOP
              NOP
              NOP
              MOV   C,  SDA
              CLR    SCL
              RLC    A
              DJNZ   R0,  RECV100
              RET
；*******通過(guò)I2C總線向某一寄存器寫(xiě)入一個(gè)字節(jié)數(shù)據(jù)*********
I2C_WRITE:   ACALL  I2C_START          ；發(fā)啟動(dòng)信號(hào)
              MOV    A， # DeviceaddressW ；調(diào)7113地址+寫(xiě)
              ACALL  I2C_SEND_1BYTE    ；發(fā)送7113地址及“寫(xiě)”命令
              ACALL  CHECK_ACK         ；檢查7113的應(yīng)答信號(hào)
              JNB     I2C_ERROR, WR200   ；應(yīng)答正確，繼續(xù)
WR100:     ACALL  I2C_STOP            ；應(yīng)答不對(duì)，返回
              RET
WR200:     MOV    A,  Subaddress        ；調(diào)寄存器地址
            ACALL  I2C_SEND_1BYTE    ；發(fā)送寄存器地址
              ACALL  CHECK_ACK         ；檢查7113的應(yīng)答信號(hào)
            JB       I2C_ERROR, WR100   ；應(yīng)答不對(duì)，返回
            MOV    A,  DATA_I2C        ；調(diào)準(zhǔn)備寫(xiě)入的數(shù)據(jù)
            ACALL  I2C_SEND_1BYTE     ；發(fā)送數(shù)據(jù)字節(jié)
              ACALL  CHECK_ACK
            JB       I2C_ERROR, WR100
            ACALL  I2C_STOP             ；發(fā)停止信號(hào)
            RET
；*******通過(guò)I2C總線讀出某一寄存器的數(shù)據(jù)*********
I2C_READ:    ACALL  I2C_START
              MOV    A, # DeviceaddressW   ；調(diào)7113地址，寫(xiě)入
              ACALL  I2C_SEND_1BYTE
              ACALL  CHECK_ACK
              JNB     I2C_ERROR, RD200
RD100:    ACALL  I2C_STOP
          RET
RD200:    MOV   A, Subaddress          ；調(diào)要讀的寄存器地址
              ACALL  I2C_SEND_1BYTE     ; 發(fā)送寄存器地址字節(jié)
              ACALL  CHECK_ACK
          JB       I2C_ERROR, RD100
          ACALL  I2C_START           ；重發(fā)起動(dòng)信號(hào)
          MOV    A, # DeviceaddressR    ；調(diào)7113地址，讀
              ACALL  I2C_SEND_1BYTE
              ACALL  CHECK_ACK
          JB       I2C_ERROR, RD100
          ACALL  I2C_RECEIVE_1BYTE  ；接收讀出的數(shù)據(jù)
          MOV    DATA_I2C,  A         ；讀出數(shù)據(jù)轉(zhuǎn)存
          ACALL  SEND_NOACK         ；發(fā)送非應(yīng)答位
          ACALL  I2C_STOP              ；停止
          RET
；***************初始化7113，配置各寄存器************************
 INIT_SAA7113:    MOV DPTR, #SAA7113_Subaddress
               MOV R7, #28
INIT100:       MOV A, #0
               MOVC  A, @A+DPTR
               MOV Subaddress,  A     ；調(diào)寄存器地址
               MOV A,#28
               MOVC  A, @A+DPTR
               MOV DATA_I2C, A       ；調(diào)寄存器配置數(shù)據(jù)
               INC  DPTR
               ACALL I2C_WRITE     ；配置1個(gè)寄存器
               JB I2C_ERROR, INIT200
               DJNZ R7,INIT100
INIT200:      RET
；***************SAA7113寄存器初始化配置數(shù)據(jù)**********************
SAA7113_Subaddress:
 DB 01H,02H,03H,04H,05H,06H,07H,08H,09H,0AH,0BH,0CH,0DH,0EH
 DB 0FH,10H,11H,12H,13H,15H,16H,17H,40H,58H,59H,5AH,5BH,5EH
    ；共28個(gè)
I2C_REG_VALUE_AI11:
 DB 08H,0C0H,33H,00H,00H,0EBH,0E0H,0B8H,01H,7EH,46H,43H,01H,01H
 DB 0FH,00H,0CH,0A7H,00H,00H,00H,00H,02H,00H,54H,07H,80H,00H
；*************對(duì)SAA7113某一寄存器的改寫(xiě)與讀出*******************
WRITE_READ:     MOV  Subaddress, #0AH   ; 設(shè)寄存器地址為0AH
                  MOV  DATA_I2C, #88H    ；改寄存器的值為88H
                  ACALL I2C_WRITE     ；改寫(xiě)
               ACALL I2C_READ      ；讀出
 
結(jié)語(yǔ)
    SAA7113在很多產(chǎn)品中都可以應(yīng)用，但其初始化與控制的原理都一樣，本文中的程序段經(jīng)過(guò)實(shí)際應(yīng)用可以保證7113正常工作，其寄存器設(shè)置參數(shù)與控制方法可以被借鑒或直接應(yīng)用。

參考文獻(xiàn)
1． 陳露晨主編. 計(jì)算機(jī)通信接口技術(shù). 成都：電子科技大學(xué)出版社，1999
2． 張洪潤(rùn)主編. 單片機(jī)應(yīng)用技術(shù)教程. 北京：清華大學(xué)出版社，1997
3． SAA7113H  Product specification / Data sheet . PHILIPS, 1999