ARM 系列 -- FS2410 開發(fā)板上的中斷編程

一、目的
中斷服務(wù)程序在操作系統(tǒng)中無疑占有非常重要的地位，編寫中斷程序不僅要會(huì)運(yùn)用底層的匯編語(yǔ)言，還要了解 ARM 的體系架構(gòu)。那這一節(jié)我們就通過中斷編程來響應(yīng) FS2410開發(fā)板上的 16 個(gè)按鍵，實(shí)現(xiàn)依次按下16個(gè)鍵時(shí)，D9~D12 四個(gè) Led 從 0~15 進(jìn)行計(jì)數(shù)，并通過上個(gè)實(shí)驗(yàn)實(shí)現(xiàn)的 uart_printf 向串口發(fā)送數(shù)據(jù) Kn is pressed!。

二、代碼
我們直接分析代碼，代碼中只有簡(jiǎn)略的注釋，必要時(shí)我會(huì)在整個(gè)代碼文件的后面對(duì)相應(yīng)的細(xì)節(jié)進(jìn)行解釋。先來分析 head.s:

@文件 head.s
.text
.global _start
_start:
@ Set vector table for interrupt
b reset
b HandleIRQ
b HandleIRQ
b HandleIRQ
b HandleIRQ
b HandleIRQ
b HandleIRQ @ handle irq interrupt here
b HandleIRQ
reset:
ldr r0, =0x53000000@ Close Watch Dog Timer
mov r1, #0x0
str r1, [r0]

@ disable all interrupts
mov r1, #0x4A000000
mov r2, #0xffffffff
str r2, [r1, #0x08] @ set INTMSK
ldr r2, =0x7ff
str r2, [r1, #0x1C] @ set INTSUBMSK

bl memory_setup@ Initialize memory setting
bl flash_to_sdram@ Copy code to sdram

msr cpsr_c, #0xd2@ set irq mode stack
ldr pc, =set_sp @ jump to addr 0x3000000
set_sp:
ldr sp, =0x31000000
msr cpsr_c, #0xdf@ set system mode stack
ldr sp, =0x32000000
bl init_irq @ Call init_irq
msr cpsr_c, #0x5f@ set system mode and open the irq

ldr sp, =0x34000000@ Set stack pointer
bl main
loop:
b loop
HandleIRQ:
sub lr, lr,#4 @ get the return addr
stmdb sp!, { r0-r12,lr } @ store used registers in stack
ldr lr, =int_return @ set retrun addr
ldr pc, =EINT_Handle @ jump to the interrup processing function
int_return:
ldmia sp!, { r0-r12,pc }^

呵呵，不知不覺 head.s 的代碼已經(jīng)很長(zhǎng)了，我們來看一下它的執(zhí)行流程:
(1) 設(shè)置中斷向量表。你也許在這里有疑問，為什么一開始就有 8 個(gè)分支跳轉(zhuǎn)指令？我們先來研究一下 ARM 如何響應(yīng)異常/中斷，看下表:

-------------------------------------------------------------
Exception Mode Address
-------------------------------------------------------------
Reset Supervisor0x00000000
Undefined Undefined0x00000004
Software InteruptSupervistor0x00000008
Prefetch AbortAbort 0x0000000C
Data AbortAbort0x00000010
IRQ (interupt)IRQ0x00000018
FIQ (fast interupt)FIQ0x0000001C
-------------------------------------------------------------

可以看出 ARM 支持 7 種異常/中斷，每種異常/中斷都有固定的地址，這個(gè)地址叫 中斷向量，一般我們會(huì)在這個(gè)地址放一條分支跳轉(zhuǎn)指令，當(dāng)異常/中斷發(fā)生時(shí)，ARM 就到這個(gè)地址執(zhí)行這個(gè)跳轉(zhuǎn)指令，從而調(diào)用相應(yīng)的中斷服務(wù)程序。

等等，這里是不是有點(diǎn)問題？呵呵，你也許已經(jīng)發(fā)現(xiàn)了，這里只有 7 種異常/中斷，那我們的程序怎么會(huì)有 8 條分支跳轉(zhuǎn)指令呢? 因?yàn)橹袛嘞蛄考吹刂?0x00000014 被ARM保留用做將來擴(kuò)展之用，但我們還需用一條指令(4字節(jié))來填充這個(gè)位置，只不過它不會(huì)被 ARM 執(zhí)行。

(2) 關(guān)閉看門狗
(3) 暫時(shí)屏蔽所有中斷。
1.地址 0x4A000008 是中斷屏寄存器 INTMSK 的端口地址，復(fù)位 INTMSK 會(huì)導(dǎo)致所有的中斷源被屏掉。
2.地址 0x4A00001C 是子中斷屏寄存器 INTSUBMSK 的端口地址，它的低 11 位對(duì)應(yīng)外部 11 個(gè)中斷源，高 21 位保留不用。復(fù)位它的低 11 位會(huì)導(dǎo)致相應(yīng)的外部中斷被屏。
(4) 初始化內(nèi)存 SDRAM 設(shè)置
(5) Self-copying: 從 Nand Flash 將自身復(fù)制到 SDRAM
(6) 進(jìn)入 IRQ 模式，設(shè)置 IRQ 模式下的堆棧寄存器
(7) 進(jìn)入系統(tǒng)模式，并設(shè)置系統(tǒng)模式下的堆棧寄存器
(8) 系統(tǒng)模式下調(diào)用 init_irq，這個(gè)函數(shù)用于初始化一些用于響應(yīng)按鍵的中斷寄存器
(9) 再次進(jìn)入系統(tǒng)模式，并打開當(dāng)前程序狀態(tài)寄存器 cpsr 的 IRQ 中斷位，這樣 ARM 就能響應(yīng) IRQ 中斷了
(10)執(zhí)行主函數(shù) main 后返回，然后進(jìn)入死循環(huán)，等待中斷發(fā)生
(11)中斷發(fā)生時(shí)，ARM 響應(yīng)中斷并于 0x00000018 處執(zhí)行 b HandleIRQ 跳轉(zhuǎn)指令調(diào)用中斷服務(wù)程序，處理完畢后返回循環(huán)處再等待下次中斷的發(fā)生，如此往復(fù)...

這就是中斷處理的基本流程了 :-)， 以下文件的代碼在前面隨筆均有詳細(xì)說明，這里就僅附簡(jiǎn)略注釋了

@ 文件 flash.s
@ 作用:設(shè)置 Nand Flash 的控制寄存器、讀取 Nand Flash
@ 中的代碼到 SDRAM 的指定位置，更多細(xì)節(jié)請(qǐng)參考我前面的隨筆
.equ NFCONF, 0x4e000000
.equ NFCMD, 0x4e000004
.equ NFADDR, 0x4e000008
.equ NFDATA, 0x4e00000c
.equ NFSTAT, 0x4e000010
.equ NFECC, 0x4e000014
.global flash_to_sdram
flash_to_sdram:
@ Save return addr
mov r10,lr

@ Initialize Nand Flash
mov r0,#NFCONF
ldr r1,=0xf830
str r1,[r0]

@ First reset and enable Nand Flash
ldr r1,[r0]
bic r1, r1, #0x800
str r1,[r0]

ldr r2,=NFCMD
mov r3,#0xff
str r3,[r2]

@ for delay
mov r3, #0x0a
1:
subs r3, r3, #1
bne 1b

@ Wait until Nand Flash bit0 is 1
wait_nfstat:
ldr r2,=NFSTAT
ldr r3,[r2]
tst r3,#0x01
beq wait_nfstat

@ Disable Nand Flash
ldr r0,=NFCONF
ldr r1,[r0]
orr r1,r1,#0x8000
str r1,[r0]

@ Initialzie stack
ldr sp,=4096

@ Set arguments and call
@ function nand_read defined in nand_read.c
ldr r0,=0x30000000
mov r1,#0
mov r2,#1024*40
bl nand_read

@ return
mov pc,r10