單片機(jī)動態(tài)掃描顯示接口

動態(tài)掃描顯示接口是單片機(jī)中應(yīng)用最為廣泛的一種顯示方式之一。其接口電路是把所有顯示器的8個筆劃段a-h同名端連在一起，而每一個顯示器的公共極COM是各自獨(dú)立地受I/O線控制。CPU向字段輸出口送出字形碼時，所有顯示器接收到相同的字形碼，但究竟是那個顯示器亮，則取決于COM端，而這一端是由I/O控制的，所以我們就可以自行決定何時顯示哪一位了。而所謂動態(tài)掃描就是指我們采用分時的方法，輪流控制各個顯示器的COM端，使各個顯示器輪流點(diǎn)亮。

在輪流點(diǎn)亮掃描過程中，每位顯示器的點(diǎn)亮?xí)r間是極為短暫的(約1ms)，但由于人的視覺暫留現(xiàn)象及發(fā)光二極管的余輝效應(yīng)，盡管實(shí)際上各位顯示器并非同時點(diǎn)亮，但只要掃描的速度足夠快，給人的印象就是一組穩(wěn)定的顯示數(shù)據(jù)，不會有閃爍感。

下圖所示就是我們的實(shí)驗(yàn)板上的動態(tài)掃描接口。由89C51的P0口能灌入較大的電流，所以我們采用共陽的數(shù)碼管，并且不用限流電阻，而只是用兩只1N4004進(jìn)行降壓后給數(shù)碼管供電，這里僅用了兩只，實(shí)際上還可以擴(kuò)充。它們的公共端則由PNP型三極管8550控制，顯然，如果8550導(dǎo)通，則相應(yīng)的數(shù)碼管就可以亮，而如果8550截止，則對應(yīng)的數(shù)碼管就不可能亮，8550是由P2.7，P2.6控制的。這樣我們就可以通過控制P27、P26達(dá)到控制某個數(shù)碼管亮或滅的目的。

下面的這個程序，就是用實(shí)驗(yàn)板上的數(shù)碼管顯示0和1。

FIRST EQU P2.7 ;第一位數(shù)碼管的位控制

SECOND EQU P2.6 ;第二位數(shù)碼管的位控制

DISPBUFF EQU 5AH ;顯示緩沖區(qū)為5AH和5BH

ORG 0000H

AJMP START

ORG 30H

START:

MOV SP,#5FH ;設(shè)置堆棧

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化，所顯示器，LED滅

MOV DISPBUFF,#0 ;第一位顯示0

MOV DISPBUFF+1,#1 ;第二握顯示1

LOOP:

LCALL DISP ;調(diào)用顯示程序

AJMP LOOP

;主程序到此結(jié)束

DISP:

PUSH ACC ;ACC入棧

PUSH PSW ;PSW入棧

MOV A,DISPBUFF ;取第一個待顯示數(shù)

MOV DPTR,#DISPTAB ;字形表首地址

MOVC A,@A+DPTR ;取字形碼

MOV P0,A ;將字形碼送P0位(段口)

CLR FIRST ;開第一位顯示器位口

LCALL DELAY ;延時1毫秒

SETB FIRST ;關(guān)閉第一位顯示器(開始準(zhǔn)備第二位的數(shù)據(jù))

MOV A,DISPBUFF+1 ;取顯示緩沖區(qū)的第二位

MOV DPTR,#DISPTAB

MOVC A,@A+DPTR

MOV P0,A ;將第二個字形碼送P0口

CLR SECOND ;開第二位顯示器

LCALL DELAY ;延時

SETB SECOND ;關(guān)第二位顯示

POP PSW

POP ACC

RET

DELAY: ;延時1毫秒

PUSH PSW

SETB RS0

MOV R7,#50

D1: MOV R6,#10

D2: DJNZ R6,$

DJNZ R7,D1

POP PSW

RET

DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

END

從上面的例子中可以看出，動態(tài)掃描顯示必須由CPU不斷地調(diào)用顯示程序，才能保證持續(xù)不斷的顯示。

上面的這個程序可以實(shí)現(xiàn)數(shù)字的顯示，但不太實(shí)用，為什么呢?這里僅是顯示兩個數(shù)字，并沒有做其他的工作，因此，兩個數(shù)碼管輪流顯示1毫秒，沒有問題，實(shí)際的工作中，當(dāng)然不可能只顯示兩個數(shù)字，還是要做其他的事情的，這樣在二次調(diào)用顯示程序之間的時間間隔就不一不定了，如果時間間隔比較長，就會使顯示不連續(xù)。而實(shí)際工作中是很難保證所有工作都能在很短時間內(nèi)完成的。況且這個顯示程序也有點(diǎn)“浪費(fèi)”，每個數(shù)碼管顯示都要占用1個毫秒的時間，這在很多合是不允許的，怎么辦呢?我們可以借助于定時器，定時時間一到，產(chǎn)生中斷，點(diǎn)亮一個數(shù)碼管，然后馬上返回，這個數(shù)碼管就會一直亮到下一次定時時間到，而不用調(diào)用延時程序了，這段時間可以留給主程序干其他的事。到下一次定時時間到則顯示下一個數(shù)碼管，這樣就很少浪費(fèi)了。

Counter EQU 59H ;計數(shù)器，顯示程序通過它得知現(xiàn)正顯示哪個數(shù)碼管

FIRST EQU P2.7 ;第一位數(shù)碼管的位控制

SECOND EQU P2.6 ;第二位數(shù)碼管的位控制

DISPBUFF EQU 5AH ;顯示緩沖區(qū)為5AH和5BH

ORG 0000H

AJMP START

ORG 000BH ;定時器T0的入口

AJMP DISP ;顯示程序

ORG 30H

START:

MOV SP,#5FH ;設(shè)置堆棧

MOV P1,#0FFH

MOV P0,#0FFH

MOV P2,#0FFH ;初始化，所顯示器，LED滅

MOV TMOD,#00000001B ;定時器T0工作于模式1(16位定時/計數(shù)模式)

MOV TH0,#HIGH(65536-2000)

MOV TL0,#LOW(65536-2000)

SETB TR0

SETB EA

SETB ET0

MOV Counter,#0 ;計數(shù)器初始化

MOV DISPBUFF,#0 ;第一位始終顯示0

MOV A,#0

LOOP:

MOV DISPBUFF+1,A ;第二位輪流顯示0-9

INC A

LCALL DELAY

CJNE A,#10,LOOP

MOV A,#0

AJMP LOOP ;在此中間可以按排任意程序，這里僅作示范。

;主程序到此結(jié)束

DISP: ;定時器T0的中斷響應(yīng)程序

PUSH ACC ;ACC入棧

PUSH PSW ;PSW入棧

MOV TH0,#HIGH(65536-2000) ;定時時間為2000個周期，約2170微秒(11.0592M)

MOV TL0,#LOW(65536-2000)

SETB FIRST

SETB SECOND ;關(guān)顯示

MOV A,#DISPBUFF ;顯示緩沖區(qū)首地址

ADD A,Counter

MOV R0,A

MOV A,@R0 ;根據(jù)計數(shù)器的值取相應(yīng)的顯示緩沖區(qū)的值

MOV DPTR,#DISPTAB ;字形表首地址

MOVC A,@A+DPTR ;取字形碼

MOV P0,A ;將字形碼送P0位(段口)

MOV A,Counter ;取計數(shù)器的值

JZ DISPFIRST ;如果是0則顯示第一位

CLR SECOND ;否則顯示第二位

AJMP DISPNEXT

DISPFIRST:

CLR FIRST ;顯示第一位

DISPNEXT:

INC Counter ;計數(shù)器加1

MOV A,Counter

DEC A ;如果計數(shù)器計到2，則讓它回0

DEC A

JZ RSTCOUNT

AJMP DISPEXIT

RSTCOUNT:

MOV Counter,#0 ;計數(shù)器的值只能是0或1

DISPEXIT:

POP PSW

POP ACC

RETI

DELAY: ;延時130毫秒

PUSH PSW

SETB RS0

MOV R7,#255

D1: MOV R6,#255

D2: NOP

NOP

NOP

NOP

DJNZ R6,D2

DJNZ R7,D1

POP PSW

RET

DISPTAB:DB 28H,7EH,0a4H,64H,72H,61H,21H,7CH,20H,60H

END

從上面的程序可以看出，和靜態(tài)顯示相比，動態(tài)掃描的程序稍有點(diǎn)復(fù)雜，不過，這是值得的。這個程序有一定的通用性，只要改變端口的值及計數(shù)器的值就可以顯示更多位數(shù)了。下面給出顯示程序的流程圖。