ARM 系列 -- FS2410 開發(fā)板上 Nand Flash 到內(nèi)存的代碼搬移

一、目的
通過將 Nand Flash 前 4K 代碼搬移到 SDRAM 中，了解如何初始化并使用 ARM 的內(nèi)存，
為編寫 ARM bootloader 和搬移內(nèi)核到內(nèi)存作準(zhǔn)備。

二、代碼
關(guān)于如何建立開發(fā)環(huán)境，在我的前一篇隨筆(FS2401 發(fā)光二極管循環(huán)點(diǎn)亮)里有介紹, 請(qǐng)
參考。要初始化并使用內(nèi)存需要了解一些很鎖碎的細(xì)節(jié)，上來(lái)就講這些知識(shí)點(diǎn)未免生澀，不
如在代碼中穿插講解來(lái)的直接。

@ 文件 head.s
@ 作用: 關(guān)閉看門狗、設(shè)置內(nèi)存、向 SDRAM 搬移 Nand Flash 的前 4K 代碼、設(shè)置堆棧、
@ 調(diào)用已經(jīng)搬移到 SDRAM 的 main 函數(shù)
.text
.global _start
_start:
ldr r0, =0x53000000 @ Close watch-dog
mov r1, #0x0
str r1, [r0]
bl memory_setup@ Initialize memory setting
bl copy_block_to_sdram @ Move code to SDRAM
ldr sp, =0x34000000 @ Set stack pointer
ldr pc, =main @ call main in SDRAM

halt_loop:
b halt_loop

copy_block_to_sdram:
mov r0, #0x0
mov r1, #0x30000000
mov r2, #4096
copy_loop:
ldmia r0!, {r3-r10}
stmia r1!, {r3-r10}
cmp r0, r2
blo copy_loop

注:看門狗(Watch Dog Timer，簡(jiǎn)稱為WDT)技術(shù)就是最常見的抗干擾技術(shù)，實(shí)際上是一個(gè)
可清零的定時(shí)計(jì)數(shù)器。

@ 文件 memory.s
@ 初始化內(nèi)存控制寄存器
.global memory_setup@ 導(dǎo)出 memory_setup, 使其對(duì)鏈接器可見
memory_setup:
mov r1, #0x48000000 @ BWSCON 內(nèi)存控制寄存器地址
adrl r2, mem_cfg_val
add r3, r1, #13*4
1:
@ write initial values to registers
ldr r4, [r2], #4
str r4, [r1], #4
cmp r1, r3
bne 1b
mov pc, lr

.align 4
mem_cfg_val:
.long 0x22111110 @ BWSCON
.long 0x00000700 @ BANKCON0
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7 9bit
.long 0x008e07a3 @ REFRESH
.long 0x000000b2 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7

注: 要理解這里的寄存器設(shè)置需要看手冊(cè)和資料， 這里簡(jiǎn)單介紹一下:
1．BWSCON：對(duì)應(yīng)BANK0-BANK7，每BANK使用4位。這4位分別表示:
a．STx：?jiǎn)?dòng)/禁止SDRAM的數(shù)據(jù)掩碼引腳，對(duì)SDRAM，此位為0；對(duì)SRAM，此位為1
b．WSx：是否使用存儲(chǔ)器的WAIT信號(hào)，通常設(shè)為0
c．DWx：使用兩位來(lái)設(shè)置存儲(chǔ)器的位寬：00-8位，01-16位，10-32位，11-保留。
d．比較特殊的是BANK0對(duì)應(yīng)的4位，它們由硬件跳線決定，只讀。
e．對(duì)于本開發(fā)板，使用兩片容量為32Mbyte、位寬為16的SDRAM組成容量為64Mbyte、
位寬為32的存儲(chǔ)器，所以其BWSCON相應(yīng)位為：0010。對(duì)于本開發(fā)板，BWSCON可設(shè)為
0x22111110：其實(shí)我們只需要將BANK6對(duì)應(yīng)的4位設(shè)為0010即可，其它的是什么值沒
什么影響，這個(gè)值是參考手冊(cè)上給出的。
2．BANKCON0-BANKCON5：我們沒用到，使用默認(rèn)值0x00000700即可
3．BANKCON6-BANKCON7：設(shè)為0x00018005
在8個(gè)BANK中，只有BANK6和BANK7可以使用SRAM或SDRAM，與BANKCON0-5有點(diǎn)不同：
a．MT([16:15])：用于設(shè)置本BANK外接的是SRAM還是SDRAM：SRAM-0b00，SDRAM-0b11
b．當(dāng)MT=0b11時(shí)，還需要設(shè)置兩個(gè)參數(shù)：
Trcd([3:2])：RAS to CAS delay，設(shè)為推薦值0b01
SCAN([1:0])：SDRAM的列地址位數(shù)，本開發(fā)板的SDRAM列地址位數(shù)為9，所以SCAN=0b01
4．REFRESH(SDRAM refresh control register)：
其中R_CNT用于控制SDRAM的刷新周期，占用REFRESH寄存器的[10:0]位，它的取值可
如下計(jì)算(SDRAM時(shí)鐘頻率就是HCLK)：
R_CNT = 2^11 + 1 – SDRAM時(shí)鐘頻率(MHz) * SDRAM刷新周期(uS)
在未使用PLL時(shí)，SDRAM時(shí)鐘頻率等于晶振頻率12MHz；SDRAM的刷新周期在SDRAM的數(shù)
據(jù)手冊(cè)上有標(biāo)明，在本開發(fā)板使用的SDRAM HY57V561620CT-H的數(shù)據(jù)手冊(cè)上，可看見
這么一行“8192 refresh cycles / 64ms”：所以，刷新周期=64ms/8192 = 7.8125 uS。

對(duì)于本實(shí)驗(yàn)，R_CNT = 2^11 + 1 – 12 * 7.8125 = 1955
REFRESH=0x008e0000 + 1955 = 0x008e07a3
5．BANKSIZE：0x000000b2
位[7]=1：Enable burst operation
位[5]=1：SDRAM power down mode enable
位[4]=1：SCLK is active only during the access (recommended)
位[2:1]=010 BANK6、BANK7對(duì)應(yīng)的地址空間: 010-128M/128M, 001-64M/64M
6．MRSRB6、MRSRB7：0x00000030
能讓我們修改的只有位[6:4](CL)，SDRAM HY57V561620CT-H不支持CL=1的情況，所以
位[6:4]取值為010(CL=2)或011(CL=3)

/* 文件 sdram.c */
/* 作用 循環(huán)點(diǎn)亮開發(fā)板上的 D9、D10、D11、D12 四個(gè)發(fā)光二極管 */
#define GPFCON (*(volatile unsigned long *)0x56000050) /* GPFCON 端口地址為0x56000050 */
#define GPFDAT (*(volatile unsigned long *)0x56000054) /* GPFDAT 端口地址為0x56000054 */

int main()
{
int i,j;
while(1) {
for (i = 0; i <4; ++i) {
GPFCON = 0x1<<(8+i*2); /* 如何設(shè)置此二寄存器使二極管發(fā)光,前一*/
GPFDAT = 0x0;/* 篇隨筆(FS2401 發(fā)光二極管循環(huán)點(diǎn)亮) */
/* 里有介紹*/
// for delay
for(j=0;j<50000;++j) ;
}
}
}

# Makefile
# 編譯上述三個(gè)代碼文件， 并鏈接生成的目標(biāo)文件,
# 再將目標(biāo)文件(ELF格式)轉(zhuǎn)換成二進(jìn)制格式文件
sdram:head.s memory.s sdram.c
arm-linux-gcc -c -o head.o head.s
arm-linux-gcc -c -o memory.o memory.s
arm-linux-gcc -c -o sdram.o sdram.c

# -Ttext 0x30000000 會(huì)使目標(biāo)文件里 ldr pc, =main 指令里的 pc 加上
# 0x30000000 這個(gè)基地址，而 #0x30000000 正是我們要將代碼搬到 SDRAM 的
# 起始地址， 更多細(xì)節(jié)請(qǐng)參考 arm-linux-ld -Ttext 的用法
arm-linux-ld -Ttext 0x30000000 head.o memory.o sdram.o -o sdram_tmp.o
arm-linux-objcopy -O binary -S sdram_tmp.o sdram
clean:
rm -f *.o
rm -f sdram

三、編譯、燒寫、測(cè)試
Make 一下就會(huì)生成我們要的文件 sdram, 將其通過 JTAG 燒入 Nand Flash 即可，Reset
一下開發(fā)板， 欣賞您的實(shí)驗(yàn)成果吧